Textverknüpfungen und ALPHA

  Entwicklung von und mit ABAP / ABAP Objects   Home  Links  Datenschutz  Impressum

führende Nullen entfernen oder hinzufügen

alt
 
DATA var_int TYPE char10 VALUE '0000098765'.
DATA var_ext TYPE char10.
CALL FUNCTION 'CONVERSION_EXIT_ALPHA_OUTPUT'
  EXPORTING
    input = var_int
  IMPORTING
    output = var_ext.
cl_demo_output=>write( |var_int = { var_int }| ).
cl_demo_output=>write( |var_ext = { var_ext }| ).
cl_demo_output=>display( ).
neu
 
DATA var_int TYPE char10 VALUE '0000098765'.
DATA(var_ext) = |{ var_int ALPHA = OUT }|.
cl_demo_output=>write( |var_int = { var_int }| ).
cl_demo_output=>write( |var_ext = { var_ext }| ).
cl_demo_output=>display( ).
DATA var_ext TYPE char10 VALUE '12345'.
DATA var_int TYPE char10.
CALL FUNCTION 'CONVERSION_EXIT_ALPHA_INPUT'
  EXPORTING
    input = var_ext
  IMPORTING
    output = var_int.
cl_demo_output=>write( |var_ext = { var_ext }| ).
cl_demo_output=>write( |var_int = { var_int }| ).
cl_demo_output=>display( ).
DATA var_ext TYPE char10 VALUE '12345'.
DATA(var_int) = |{ var_ext ALPHA = IN }|.
cl_demo_output=>write( |var_ext = { var_ext }| ).
cl_demo_output=>write( |var_int = { var_int }| ).
cl_demo_output=>display( ).
 
 

statische und variable Texte oder Werte als Text verknüpfen

alt
 
DATA:
  lv_order_num TYPE n LENGTH 10 VALUE '33557777',
  lv_index     TYPE i VALUE 1966,
  lv_char20    TYPE c LENGTH 20.
...
WRITE lv_index TO lv_char20 LEFT-JUSTIFIED NO-GROUPING.
CONDENSE lv_char20 NO-GAPS.
CONCATENATE 'The order' lv_order_num 'with index' lv_char20
            'has been created successfully'
  INTO DATA(lv_msg) SEPARATED BY space.
MESSAGE lv_msg TYPE 'S'.
neu
 
DATA:
  lv_order_num TYPE n LENGTH 10 VALUE '33557777',
  lv_index     TYPE i VALUE 1966.
...
DATA(lv_msg) = |The order { lv_order_num } with index { lv_index } has been created successfully|.
MESSAGE lv_msg TYPE 'S'.
CONCATENATE 'The order' lv_order_num 'is created on'
            sy-datum 'at' sy-uzeit 'by' sy-uname
  INTO DATA(lv_msg) SEPARATED BY space.
DATA(lv_msg) = |The order { order_num } is created on { sy-datum } at { sy-uzeit } by { sy-uname } |.